4ButtonKeypad/4ButtonKeypad.ino

 //Recommend reading: https://www.arduino.cc/reference/en/
 
 //Buttons go 1-4 from Top to bottom
 
 //This project uses an Arduino Pro Micro (also known as an Arduino Leonardo?)

 //If using an clone arduino board, you may also need the USB driver from http://www.wch-ic.com/downloads/CH341SER_EXE.html before you will be able to upload

//Includes
//These can be installed in the arduino IDE by clicking on tools in the top bar, then manage libraries.
#include <EasyButton.h>   //Used to define a button and debounces it
#include "HID-Project.h"  //Lets us simulate keyboard presses.

////////////////////////////////////
///////  PIN DEFINITIONS  //////////
////////////////////////////////////
//These numbers refer to the physical GPIO pins on the board

//LEDS
#define LED1 3
#define LED2 5
#define LED3 6
#define LED4 9

#define LED_TIME_OUT 10000        //How long it will take for the LEDs to turn off after a button press, in milliseconds
#define LED_MAX_BRIGHTNESS 100    //Max brightness of LEDs, from 0-255. Note that this is not really linear.
#define LED_MIN_BRIGHTNESS 100    //Min brightness of LEDs, from 0-255. Note that this is not really linear. 0 is off.

unsigned long ledTickTime = 0;    //Time since the last time the LED state was updated 
unsigned long lastPressTime = 0;  //Time since the last button was pressed or released
uint8_t ledBrightness = 100;      //Brightness that the LEDs should be aiming for
bool ledOn = false;               //Should the LEDs turning/staying on or off

//Buttons
#define BUTTON1 A3
#define BUTTON2 A2 
#define BUTTON3 A1
#define BUTTON4 A0

//Using the EasyButton library we create 4 buttons, with each button being connected to a GPIO pin as defined above, and having a 35ms debounce time. From memory, these do not have internal pullup resistors, and are not inverted. Hence the two falses.
EasyButton button1(BUTTON1, 35, false, false);
EasyButton button2(BUTTON2, 35, false, false);
EasyButton button3(BUTTON3, 35, false, false);
EasyButton button4(BUTTON4, 35, false, false);

//Standard Arduino setup function. Code that only needs to run once goes here
void setup() {
  Keyboard.begin();
  
  //LEDS - Setting the LED pins to be outputs. Normally, the buttons would be set as inputs, but they are handled by that library.
  pinMode(LED1, OUTPUT);
  pinMode(LED2, OUTPUT);
  pinMode(LED3, OUTPUT);
  pinMode(LED4, OUTPUT);

  //Here we output a PWM signal to the LEDs, where 0 will be off, and 255 is brightest
  analogWrite(LED1, ledBrightness);
  analogWrite(LED2, ledBrightness);
  analogWrite(LED3, ledBrightness);
  analogWrite(LED4, ledBrightness);

  //BUTTONS - setup buttons using library.
  button1.begin();
  button2.begin();
  button3.begin();
  button4.begin();  
}


//Code that is run constantly goes here
void loop() {
  
  //Read all the buttons
  button1.read();
  button2.read();
  button3.read();
  button4.read();

  ////////////////////////////////////
  ///////////  Buttons  //////////////
  ////////////////////////////////////

  //This should be pretty self explanitory. Make sure to always release a button.
  
  /*
    Also updates the lastPressTime on press and release. 
    If only release, then Lights wont turn on when pressed, and if only when pressed depending on hold length lights may turn off instantly after release. 
    Lights will not turn off while button is held, as lastPressTime will be updated each loop while button is pressed.
  */

  // Depending on what you want to do, Keyboard.write() may be more useful to you than Keyboard.press(). Check the Keyboard library docs.

  // 1st (Top) Button
  if(button1.isPressed())
  {
    Keyboard.press(KEY_LEFT_ALT);
    lastPressTime = millis();
  }

  else if(button1.wasReleased())
  {
    Keyboard.release(KEY_LEFT_ALT);
    lastPressTime = millis();
  }

  // 2nd Button
  if(button2.isPressed())
  {
    Keyboard.press(KEY_LEFT_CTRL);
    lastPressTime = millis();
  }

  else if(button2.wasReleased())
  {
    Keyboard.release(KEY_LEFT_CTRL);
    lastPressTime = millis();
  }

  // 3rd Button
  if(button3.isPressed())
  {
    Keyboard.press(KEY_LEFT_SHIFT);
    lastPressTime = millis();
  }

  else if(button3.wasReleased())
  {
    Keyboard.release(KEY_LEFT_SHIFT);
    lastPressTime = millis();
  }

  // 4th (Bottom) Button
  if(button4.isPressed())
  {
    Keyboard.press(KEY_SPACE);
    lastPressTime = millis();
  }

  else if(button4.wasReleased())
  {
    Keyboard.release(KEY_SPACE);
    lastPressTime = millis();
  }

  ////////////////////////////////////
  ///////////  Lights  ///////////////
  ////////////////////////////////////

  //If the time between now and the last time the buttons were pushed is greater than the time set in LED_TIME_OUT, set the LEDs to turn off, otherwise turn them on.
  if((millis() - lastPressTime) > LED_TIME_OUT)
  {
    ledOn = false;
  }
  else 
  {
    ledOn = true;
  }
  
  //This part fades the LEDs to their new state
  if ((millis() - ledTickTime) > 10)  //Update brightness every 10 milliseconds
  {
    ledTickTime = millis(); 

    //If led turning off, and brightness is still not low enough, decrement brihtness by 1
    if(!ledOn && (ledBrightness > LED_MIN_BRIGHTNESS))
    {
      ledBrightness=ledBrightness-1;
    }

    //If led turning on, and brightness is still not high enough, increment brihtness by 10
    else if(ledOn && (ledBrightness < LED_MAX_BRIGHTNESS))
    {
      ledBrightness=ledBrightness+10; //Making this 10 instead of 1 means it will fade in faster than it fades out. Easier than making another setup with another ledTickTime2 or something variable.
    }

    //Set new brightness on pins
    analogWrite(LED1, ledBrightness);
    analogWrite(LED2, ledBrightness);
    analogWrite(LED3, ledBrightness);
    analogWrite(LED4, ledBrightness); 
  }
}